;
; Bitmap font
;

;
; Write text on screen
;
; Expects a 4x8 font on "font" label.
;
; in: [a : x]: text to write
;     b, y: (x, y) dst coords
put_text:
    push y
    push b

put_text_loop:
    ld y, [a : x]
    cmp y, 0
    bz
    jmp put_text_exit

    sub y, 32

    push a
    push x

    rol y, 5
    ld x, y
    and x, 31
    and y, 224

    ld a, >font
    add a, x

    ld x, <font
    add x, y
    bo
    inc a

    call put_text_c

    pop x
    pop a

    inc x
    bo
    inc a

    pop b
    add b, 4
    push b

    jmp put_text_loop

put_text_exit:
    pop b
    pop y
    ret

put_text_c:
    ; settings mode
    ld y, 128
    ld b, 0xb0
    port b, y

    ; setup
    inc b

    ; addr: char sprite
    ld y, x
    port b, y
    ld y, a
    port b, y

    ; x
    ld y, [sp + 4]
    port b, y

    ; y
    ld y, [sp + 5]
    port b, y

    ; w
    ld y, 4
    port b, y
    ; h
    ld y, 8
    port b, y

    ; blit
    dec b
    ; write, transparent
    ld y, 3
    port b, y
    ret

;
; in: [a : x]: number
;     b, y: (x, y) dst coords
;     stack: 1 byte digits
put_bcd_number:
    push y
    push b

put_bcd_number_loop:
    ld y, [a : x]
    inc x
    bo
    inc a

    add y, 16

    push a
    push x

    rol y, 5
    ld x, y
    and x, 31
    and y, 224

    ld a, >font
    add a, x

    ld x, <font
    add x, y
    bo
    inc a

    call put_text_c

    pop x
    pop a

    pop b
    add b, 4
    push b

    ld y, [sp + 4]
    dec y
    ld [sp + 4], y
    bnz
    jmp put_bcd_number_loop

    pop b
    pop y
    ret