1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
|
; ******************************************************
; ** Librer�a de rutinas SDCC para Amstrad CPC **
; ** Ra�l Simarro (Artaburu) - 2009, 2012 **
; ******************************************************
;*************************************
; KEYBOARD
;*************************************
.globl _cpc_AnyKeyPressed
MAX_KEYS = 12
_cpc_AnyKeyPressed::
call hacer_tiempo
call hacer_tiempo
call hacer_tiempo
LD A,#0x40
bucle_deteccion_tecla:
PUSH AF
CALL cpc_TestKeyboard ;en A vuelve los valores de la linea
OR A
JP NZ, tecla_pulsada ; retorna si no se ha pulsado ninguna tecla
POP AF
INC A
CP #0x4a
JP NZ, bucle_deteccion_tecla
LD HL,#0
RET
tecla_pulsada:
POP AF
LD HL,#1
RET
hacer_tiempo:
LD A,#254
bucle_previo_deteccion_tecla:
PUSH AF
POP AF
dec A
Jr nZ, bucle_previo_deteccion_tecla
ret
.globl _cpc_AssignKey
_cpc_AssignKey::
LD HL,#2
ADD HL,SP
LD E,(HL) ;E-> numero tecla
INC HL
;INC HL
LD A,(HL) ;linea, byte
INC HL
LD B,(HL) ;DE tiene el valor de la tecla a escribir en la tabla
; En A se tiene el valor de la tecla seleccionada a comprobar [0..11]
;___________________________________________________________________
; ;En A viene la tecla a redefinir (0..11)
SLA E
LD D,#0
LD HL, #tabla_teclas
ADD HL,DE ;Nos colocamos en la tecla a redefinir y la borramos
LD (HL),#0XFF
INC HL
LD (HL),#0XFF
DEC HL
PUSH HL
;call ejecutar_deteccion_teclado ;A tiene el valor del teclado
; A tiene el byte (<>0)
; B tiene la linea
;guardo linea y byte
POP HL
LD (HL),A ;byte
INC HL
LD (HL),B
RET
.globl _cpc_TestKey
_cpc_TestKey::
LD HL,#2
ADD HL,SP
LD L,(HL) ; En A se tiene el valor de la tecla seleccionada a comprobar [0..11]
SLA L
INC L
LD H,#0
LD DE,#tabla_teclas
ADD HL,DE
LD A,(HL)
CALL cpc_TestKeyboard ; esta rutina lee la l�nea del teclado correspondiente
DEC HL ; pero s�lo nos interesa una de las teclas.
and (HL) ;para filtrar por el bit de la tecla (puede haber varias pulsadas)
CP (HL) ;comprueba si el byte coincide
LD H,#0
JP Z,pulsado
LD L,H
RET
pulsado:
LD L,#1
RET
.globl _cpc_RedefineKey
_cpc_RedefineKey::
LD HL,#2
ADD HL,SP
LD L,(HL)
SLA L
LD H,#0
LD DE,#tabla_teclas
ADD HL,DE ;Nos colocamos en la tecla a redefinir
LD (HL),#0XFF ; y la borramos
INC HL
LD (HL),#0XFF
DEC HL
PUSH HL
CALL ejecutar_deteccion_teclado ;A tiene el valor del teclado
LD A,D
; A tiene el byte (<>0)
; B tiene la linea
;guardo linea y byte
POP HL ;recupera posici�n le�da
LD A,(linea)
LD (HL),A ;byte
INC HL
LD A,(bte)
LD (HL),A
RET
ejecutar_deteccion_teclado:
LD A,#0x40
bucle_deteccion_tecla1:
PUSH AF
LD (bte),A
CALL cpc_TestKeyboard ;en A vuelve los valores de la linea
OR A
JR NZ, tecla_pulsada1 ; retorna si no se ha pulsado ninguna tecla
POP AF
INC A
CP #0x4A
JR NZ, bucle_deteccion_tecla1
JR ejecutar_deteccion_teclado
tecla_pulsada1:
LD (linea),A
POP AF
CALL comprobar_si_tecla_usada
RET NC
JR bucle_deteccion_tecla1
comprobar_si_tecla_usada: ; A tiene byte, B linea
LD B,#MAX_KEYS ;numero m�ximo de tecla redefinibles
LD IX,#tabla_teclas
LD C,(IX)
bucle_bd_teclas: ;comprobar byte
LD A,(linea)
LD C,(IX)
CP (IX)
JR Z, comprobar_linea
INC IX
INC IX
DJNZ bucle_bd_teclas
SCF
CCF
RET ; si vuelve despu�s de comprobar, que sea NZ
comprobar_linea: ;si el byte es el mismo, mira la linea
LD A,(bte)
CP 1 (IX) ; esto es (ix+1)
JR Z, tecla_detectada ; Vuelve con Z si coincide el byte y la linea
INC IX
INC IX
DJNZ bucle_bd_teclas
SCF
CCF
RET ; si vuelve despu�s de comprobar, que sea NZ
tecla_detectada:
SCF
RET
.globl _cpc_DeleteKeys
_cpc_DeleteKeys:: ;borra la tabla de las teclas para poder redefinirlas todas
LD HL,#tabla_teclas
LD DE,#tabla_teclas+#1
LD BC, #MAX_KEYS
LD (HL),#0xFF
LDIR
RET
.globl _cpc_TestKeyF
_cpc_TestKeyF::
LD HL,#2
ADD HL,SP
LD L,(HL)
SLA L
INC L
LD H,#0
LD DE,#tabla_teclas
ADD HL,DE
LD A,(HL)
SUB #0X40
EX DE,HL
LD HL,#keymap ;; LEE LA L�NEA BUSCADA DEL KEYMAP
LD C,A
LD B,#0
ADD HL,BC
LD A,(HL)
EX DE,HL
DEC HL ; PERO S�LO NOS INTERESA UNA DE LAS TECLAS.
AND (HL) ;PARA FILTRAR POR EL BIT DE LA TECLA (PUEDE HABER VARIAS PULSADAS)
CP (HL) ;COMPRUEBA SI EL BYTE COINCIDE
LD H,#0
JP NZ,#pulsado_cpc_TestKeyF
LD L,H
RET
pulsado_cpc_TestKeyF:
LD L,#1
RET
.globl _cpc_ScanKeyboard
_cpc_ScanKeyboard::
DI ;1 #0X#0X%%#0X#0X C P C VERSION #0X#0X%%#0X#0X FROM CPCWIKI
LD HL,#keymap ;3
LD BC,#0XF782 ;3
OUT (C),C ;4
LD BC,#0XF40E ;3
LD E,B ;1
OUT (C),C ;4
LD BC,#0XF6C0 ;3
LD D,B ;1
OUT (C),C ;4
.DB #0XED,#0X71 ; 4 OUT (C),0
LD BC,#0XF792 ;3
OUT (C),C ;4
LD A,#0X40 ;2
LD C,#10 ;2 44
loop_cpc_scankeyboard:
LD B,D ;1
OUT (C),A ;4 SELECT LINE
LD B,E ;1
INI ;5 READ BITS AND WRITE INTO KEYMAP
INC A ;1
DEC C ;1
JR NZ,loop_cpc_scankeyboard ;2/3 9*16+1*15=159
LD BC,#0XF782 ;3
OUT (C),C ;4
EI ;1 8 =209 MICROSECONDS
RET
cpc_TestKeyboard:: ;Tomado de las rutinas b�sicas que aparecen
;en los documentos de Kevin Thacker
DI
LD BC,#0XF782
OUT (C),C
LD BC, #0XF40E
OUT (C), C
LD BC, #0XF6C0
OUT (C), C
.DB #0XED,#0X71 ; OUT (C),0
LD BC, #0XF792
OUT (C), C
DEC B
OUT (C), A
LD B, #0XF4
IN A, (C)
LD BC, #0XF782
OUT (C), C
DEC B
.DB #0XED,#0X71 ; OUT (C),0
CPL
EI
RET
linea:
.DB #0
bte:
.DB #0
keymap:
.DB #0
.DB #0
.DB #0
.DB #0
.DB #0
.DB #0
.DB #0
.DB #0
.DB #0
.DB #0
;teclado_usable ; teclas del cursor, cada tecla est� definida por su bit y su l�nea.
.globl _cpc_keys_table
_cpc_keys_table:
tabla_teclas:
tecla_0_x: .DW #0xffff ; bit 0, l�nea 2
tecla_1_x: .DW #0xffff ; bit 1, l�nea 1
tecla_2_x: .DW #0xffff ; bit 0, l�nea 1
tecla_3_x: .DW #0xffff ; bit 0, l�nea 4
tecla_4_x: .DW #0xffff ; bit 0, l�nea 2
tecla_5_x: .DW #0xffff ; bit 1, l�nea 1
tecla_6_x: .DW #0xffff ; bit 0, l�nea 1
tecla_7_x: .DW #0xffff ; bit 0, l�nea 4
tecla_8_x: .DW #0xffff ; bit 0, l�nea 4
tecla_9_x: .DW #0xffff ; bit 0, l�nea 4
tecla_10_x: .DW #0xffff ; bit 0, l�nea 4
tecla_11_x: .DW #0xffff ; bit 0, l�nea 4
; For increasing keys available just increase this word table
.DB #0
|
