path: root/game/main.asm

.org 0

.equ INT_VECTOR 0xff00

    call init

;
; Menu entry point
;
menu:
    call clear_screen

menu_loop:
    halt

    call stars_update
    call menu_draw

    ; read controller 1
    ld b, 0xf0
    port b, b

    ; start
    bit b, 7
    bnz
    jmp menu_loop

;
; Gameplay entry point
;
play:
    call init_game

game_loop:
    halt

    call entities_erase
    call stars_update
    call entities_update
    call entities_draw
    call update_hud

    ; read controller 1
    ld b, 0xf0
    port b, b

    ; select to exit
    bit b, 6
    bnz
    jmp game_loop

    ; see if the hiscore needs updating

    ; 6 digits to compare
    ld y, 6
    push y

    ld x, <score
    ld a, >score
    ld y, <hiscore
    ld b, >hiscore
update_hiscore_loop:
    cmpi
    bc
    jmp update_no_hiscore
    bnz
    jmp update_new_hiscore

    push y
    ld y, [sp + 1]
    dec y
    ld [sp + 1], y
    pop y
    bno
    jmp update_hiscore_loop

update_new_hiscore:
    ; new hiscore!
    ld x, <score
    ld a, >score
    ld y, <hiscore
    ld b, >hiscore
    ldi
    ldi
    ldi
    ldi
    ldi
    ldi

update_no_hiscore:
    pop y
    jmp menu

;
; Setup the game after the menu
;
init_game:
    call entities_init

    ; set player initial coordinates
    ld x, <player_coord
    ld a, >player_coord

    ld y, 56
    ld [a : x], y
    inc x
    bo
    inc a
    ld y, 104
    ld [a : x], y

    ; clear score
    ld y, <score
    ld b, >score
    ; this is all zeroes that we use
    ; to erase things on screen etc
    ld x, 0
    ld a, 0xa0
    ldi
    ldi
    ldi
    ldi
    ldi
    ldi

    halt

    call clear_screen
    call entities_draw

    ret

;
; Update the HUD (score, lives, etc)
;
update_hud:
    ; erase

    ; settings mode
    ld y, 128
    ld b, 0xb0
    port b, y

    ; setup
    inc b

    ; addr: bg data
    ld y, 0
    port b, y
    ld y, 0xa0
    port b, y

    ; x
    inc x
    bo
    inc a
    ld y, 100
    port b, y

    ; y
    inc x
    bo
    inc a
    ld y, 4
    port b, y

    ; w
    ld y, 25
    port b, y
    ; h
    ld y, 8
    port b, y

    ; blit
    dec b
    ; write, no transparent
    ld y, 1
    port b, y

    ; 6 digits
    ld x, 6
    push x

    ; addr of the BCD number
    ld x, <score
    ld a, >score
    ; where we want the text
    ld b, 100
    ld y, 4

    call put_bcd_number

    pop x
    ret

;
; Add points to the score
;
; in: y points (1 to 10)
add_score:
    ; update score
    ld x, <score
    ld a, >score
    add x, 5
    bo
    inc a

    ld b, 6
add_score_loop:
    push b

    ld b, [a : x]
    add b, y
    ld [a : x], b
    cmp b, 10
    bnc
    jmp add_score_carry

    pop b
    ret

add_score_carry:
    sub b, 10
    ld [a : x], b

    ld y, 1

    dec x
    bo
    dec a

    pop b
    dec b
    bnz
    jmp add_score_loop
    ret

;
; Helper to clear the screen
;
clear_screen:
    ; erase the screen
    ld b, 0
    ld a, 0xbf
    ld x, 0
    ld y, 0x40
fill_loop:
    ld [a : x], b
    inc x
    bno
    jmp fill_loop
    inc a
    dec y
    bnz
    jmp fill_loop
    ret

;
; Draws the menu
;
menu_draw:
    ; hiscore
    ld x, <hiscore_text
    ld a, >hiscore_text
    ld b, 44
    ld y, 10
    call put_text

    ; 6 digits
    ld x, 6
    push x

    ; addr of the BCD number
    ld x, <hiscore
    ld a, >hiscore
    ; where we want the text
    ld b, 60
    ld y, 10

    call put_bcd_number

    pop x

    ; settings mode
    ld y, 128
    ld b, 0xb0
    port b, y

    ; setup
    inc b

    ; addr: title sprite
    ld y, <title
    port b, y
    ld y, >title
    port b, y

    ; x
    ld y, 26
    port b, y

    ; y
    ld y, 40
    port b, y

    ld y, 76
    port b, y
    ld y, 21
    port b, y

    ; blit
    dec b
    ; write, transparent
    ld y, 3
    port b, y

    ld x, <press_start_text
    ld a, >press_start_text
    ld b, 40
    ld y, 84
    call put_text

    ; settings mode
    ld y, 128
    ld b, 0xb0
    port b, y

    ; setup
    inc b

    ; addr: usebox logo sprite
    ld y, <usebox
    port b, y
    ld y, >usebox
    port b, y

    ; x
    ld y, 44
    port b, y

    ; y
    ld y, 118
    port b, y

    ld y, 40
    port b, y
    ld y, 8
    port b, y

    ; blit
    dec b
    ; write, transparent
    ld y, 3
    port b, y
    ret

;
; Init the TR8 (setup an int handler)
;
init:
    ; setup an int handler so we
    ; can use the frame int to sync
    ld a, >INT_VECTOR
    ld x, <INT_VECTOR
    ld b, <int_handler
    ld [a : x], b
    inc x
    ld b, >int_handler
    ld [a : x], b

    ; enable interrupts
    cif
    ret

int_handler:
    iret

.include "text.asm"
.include "random.asm"
.include "starfield.asm"
.include "entities.asm"
.include "player.asm"
.include "bullet.asm"

; in unpacked BCD format
hiscore:
    .db 0, 1, 0, 0, 0, 0
score:
    .db 0, 0, 0, 0, 0, 0

;
; entity data
;
entities:
    ; type
    .db ET_PLAYER
    ; x, y
player_coord:
    .db 0, 0
    ; frame
    .db 0
    .dw player_sprite
    .dw player_update

    ; 16 entities
    .ds 128, 0

    ; end of list
    .db ET_END

; sprite data
player_sprite:
    .incpng "assets/player.png"
pbullet_sprite:
    .incpng "assets/pbullet.png"

; starfield data
stars:
    ; video addr, speed, color
    .dw 0xc361
    .db 1, 15
    .dw 0xc204
    .db 1, 6
    .dw 0xcdf9
    .db 1, 15
    .dw 0xdb87
    .db 1, 3
    .dw 0xd242
    .db 1, 15
    .dw 0xdeea
    .db 1, 6
    .dw 0xe7af
    .db 1, 15
    .dw 0xed68
    .db 1, 3
    .dw 0xf812
    .db 1, 15
    .dw 0xfbca
    .db 1, 13
    .dw 0xc361
    .db 2, 8
    .dw 0xc204
    .db 2, 9
    .dw 0xcdf9
    .db 3, 7
    .dw 0xdb87
    .db 3, 4
    .dw 0xd242
    .db 2, 8
    .dw 0xdeea
    .db 3, 9
    .dw 0xe7af
    .db 3, 6
    .dw 0xed68
    .db 2, 9
    .dw 0xf812
    .db 3, 14
    .dw 0xfbca
    .db 2, 3
    ; end of list
    .dw 0xffff

; menu data
title:
    .incpng "assets/title.png"
font:
    .incpng "assets/font.png"
usebox:
    .incpng "assets/usebox.png"

; texts
press_start_text:
    .str "PRESS START!"
    .db 0
hiscore_text:
    .str "HI:"
    .db 0